web-dev-qa-db-ja.com

クラシックを使用したxmlデータの読み取りASP

私は次のように古典的なaspでxmlデータを読み取るためのコードを書きました：

<%


 Dim objxml
    Set objxml = Server.CreateObject("Microsoft.XMLDOM")
    objxml.async = False
    objxml.load ("/abc.in/xml.xml")



set ElemProperty = objxml.getElementsByTagName("Product")
set ElemEN = objxml.getElementsByTagName("Product/ProductCode")
set Elemtown = objxml.getElementsByTagName("Product/ProductName")
set Elemprovince = objxml.getElementsByTagName("Product/ProductPrice")  

Response.Write(ElemProperty)
Response.Write(ElemEN) 
Response.Write(Elemprovince)
For i=0 To (ElemProperty.length -1) 

    Response.Write " ProductCode = " 
    Response.Write(ElemEN) 
    Response.Write " ProductName = " 
    Response.Write(Elemtown) & "<br>"
    Response.Write " ProductPrice = " 
    Response.Write(Elemprovince) & "<br>"

next

Set objxml = Nothing 
%>

このコードは適切な出力を提供していません。私を助けてください。

Xmlは次のとおりです。

<Product>
   <ProductCode>abc</ProductCode>
   <ProductName>CC Skye Hinge Bracelet Cuff with Buckle in Black</ProductName>
</Product>
xmlasp-classic
7
Rash

これを試して：

<%   

Set objXMLDoc = Server.CreateObject("MSXML2.DOMDocument.3.0")    
objXMLDoc.async = False    
objXMLDoc.load Server.MapPath("/abc.in/xml.xml")

Dim xmlProduct       
For Each xmlProduct In objXMLDoc.documentElement.selectNodes("Product")
     Dim productCode : productCode = xmlProduct.selectSingleNode("ProductCode").text   
     Dim productName : productName = xmlProduct.selectSingleNode("ProductName").text   
     Response.Write Server.HTMLEncode(productCode) & " "
     Response.Write Server.HTMLEncode(productName) & "<br>"   
Next   

%>

ノート：

  • Microsoft.XMLDOMを使用しないでください明示的なMSXML2.DOMDocument.3.0を使用してください
  • 使用する Server.MapPath仮想パスを解決する
  • selectNodesの代わりにselectSingleNodeとgetElementsByTagNameを使用してください。 getElementsByTagNameはすべての子孫をスキャンするため、予期しない結果が返される可能性があります。戻り値が1つしかないことがわかっている場合でも、常に結果にインデックスを付ける必要があります。
  • 常にServer.HTMLEncode応答に送信するときのデータ。
  • 奇妙な場所に（）を入れないでください。これはJScriptではなくVBScriptです。
10
AnthonyWJones

Xmlが与えられた場合のデータの読み取り方法の例を次に示します。

<Products>
  <Product> 
    <ProductCode>abc</ProductCode> 
    <ProductName>CC Skye Hinge Bracelet Cuff with Buckle in Black</ProductName> 
  </Product>
  <Product> 
    <ProductCode>dfg</ProductCode> 
    <ProductName>another product</ProductName></Product>
</Products>

次のスクリプト

<%

Set objXMLDoc = Server.CreateObject("Microsoft.XMLDOM") 
objXMLDoc.async = False 
objXMLDoc.load("xml.xml") 

Set Root = objXMLDoc.documentElement
Set NodeList = Root.getElementsByTagName("Product")

For i = 0 to NodeList.length -1
  Set ProductCode = objXMLDoc.getElementsByTagName("ProductCode")(i)
  Set ProductName = objXMLDoc.getElementsByTagName("ProductName")(i)
  Response.Write ProductCode.text & " " & ProductName.text & "<br>"
Next

Set objXMLDoc = Nothing

%>

与える

abc CC Skye Hinge Bracelet Cuff with Buckle in Black
dfg another product
4
peter