web-dev-qa-db-ja.com

他のxslタグのxpath値としてのxsl：variable

xsl:variableで問題が発生しています。別のXMLノード属性の値に依存する値を持つ変数を作成したいのですが。これはうまくいきます。しかし、XPathを表す文字列値で変数を作成しようとすると、後のXSLタグでXPathとして使用しようとしても機能しません。

<xsl:variable name="test">  
  <xsl:choose>
    <xsl:when test="node/@attribute=0">string/represent/xpath/1</xsl:when>
    <xsl:otherwise>string/represent/xpath/2</xsl:otherwise>
  </xsl:choose>       
</xsl:variable>                 
<xsl:for-each select="$test">
  [...]
</xsl:for-each>

私が試した： xsl変数でxsl変数を使用する方法 および xsl：for-eachの選択で問題が発生し、xsl：variableを使用 しかし、結果はありません。

xsltdynamicxpath
16
Igor Milla

この場合のように、それらのパスが事前にわかっている場合は、次を使用できます。

<xsl:variable name="vCondition" select="node/@attribute = 0"/>
<xsl:variable name="test" select="actual/path[$vCondition] |
                                  other/actual/path[not($vCondition)]"/>
12
user357812

XPath式の動的評価は、XSLT（1.0と2.0の両方）では通常サポートされていません。

各ロケーションパスを要素名に制限するだけであれば、かなり一般的な動的XPathエバリュエーターを実装できます：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:param name="inputId" select="'param/yyy/value'"/>

 <xsl:variable name="vXpathExpression"
  select="concat('root/meta/url_params/', $inputId)"/>

 <xsl:template match="/">
  <xsl:value-of select="$vXpathExpression"/>: <xsl:text/>

  <xsl:call-template name="getNodeValue">
    <xsl:with-param name="pExpression"
         select="$vXpathExpression"/>
  </xsl:call-template>
 </xsl:template>

 <xsl:template name="getNodeValue">
   <xsl:param name="pExpression"/>
   <xsl:param name="pCurrentNode" select="."/>

   <xsl:choose>
    <xsl:when test="not(contains($pExpression, '/'))">
      <xsl:value-of select="$pCurrentNode/*[name()=$pExpression]"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:call-template name="getNodeValue">
        <xsl:with-param name="pExpression"
          select="substring-after($pExpression, '/')"/>
        <xsl:with-param name="pCurrentNode" select=
        "$pCurrentNode/*[name()=substring-before($pExpression, '/')]"/>
      </xsl:call-template>
    </xsl:otherwise>
   </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

この変換がこのXMLドキュメントに適用される場合：

<root>
  <meta>
    <url_params>
      <param>
        <xxx>
          <value>5</value>
        </xxx>
      </param>
      <param>
        <yyy>
          <value>8</value>
        </yyy>
      </param>
    </url_params>
  </meta>
</root>

必要な正しい結果が生成されます：

root/meta/url_params/param/yyy/value: 8
13
Dimitre Novatchev

これは、XSLT 1.0では本来可能ではありませんが、dynなどの拡張ライブラリを使用できます。

http://www.exslt.org/dyn/functions/evaluate/dyn.evaluate.html

dyn:evaluate関数は、文字列をXPath式として評価します。

2
Zkoh