web-dev-qa-db-ja.com

変数が要素のセットに属しているかどうかを確認するXSLT式

私はこのようなコードを持っています：

  <xsl:if test="$k='7' or $k = '8' or $k = '9'">

この式をSQLなどの形式で配置する方法はありますか？

   k IN (7, 8, 9)

Ty :)

xslt
17
majkinetor

XSLT/XPath 1.0：

<!-- a space-separated list of valid values -->
<xsl:variable name="list" select="'7 8 9'" />

<xsl:if test="
  contains( 
    concat(' ', $list, ' '),
    concat(' ', $k, ' ')
  )
">
  <xsl:value-of select="concat('Item ', $k, ' is in the list.')" />
</xsl:if>

必要に応じて、他のセパレーターを使用できます。

XSLT/XPath 2.0では、次のようなことができます。

<xsl:variable name="list" select="fn:tokenize('7 8 9', '\s+')" />

<xsl:if test="fn:index-of($list, $k)">
  <xsl:value-of select="concat('Item ', $k, ' is in the list.')" />
</xsl:if>

ドキュメント構造を使用してリストを定義できる場合は、次のことができます。

<!-- a node-set defining the list of currently valid items -->
<xsl:variable name="list" select="/some/items[1]/item" />

<xsl:template match="/">
  <xsl:variable name="k" select="'7'" />

  <!-- test if item $k is in the list of valid items -->
  <xsl:if test="count($list[@id = $k])">
    <xsl:value-of select="concat('Item ', $k, ' is in the list.')" />
  </xsl:if>
</xsl:template>
22
Tomalak

プロセッサがXPath2.0をサポートしている場合は、$kを次のようなシーケンスと比較できます。

<xsl:if test="$k = (7, 8, 9)">

この特定のケースでは、範囲演算子を使用することもできます。

<xsl:if test="$k = (7 to 9)">

明示的な型キャストは必要ありません。 Saxon-HE 9.8.0.12N（XSLT 3.0）でテスト済み。

XMLの例：

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <node>5</node>
    <node>6</node>
    <node>7</node>
    <node>9</node>
    <node>10</node>
    <node>79</node>
    <node>8</node>
</root>

スタイルシート：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="3.0">

    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="root">
        <xsl:copy>
            <xsl:apply-templates select="node"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="node">
        <xsl:variable name="k" select="text()"/>
        <xsl:if test="$k = (7 to 9)">
            <xsl:copy-of select="."/>
        </xsl:if>
    </xsl:template>

</xsl:stylesheet>

結果：

<?xml version="1.0" encoding="UTF-8"?>
<root>
   <node>7</node>
   <node>9</node>
   <node>8</node>
</root>
6
CoDEmanX