zshでのLS_COLORSのテスト

Question

数年前、LS_COLORSで設定された色に従って、各タイプのファイルを対応する色で印刷する興味深いコードスニペットを見つけました。残念ながら、リンクを思い出せなくなりました。

これが問題のスニペットtest_colors.shです

eval $(echo "no:global default;fi:normal file;di:directory;ln:symbolic link;pi:named pipe;so:socket;do:door;bd:block device;cd:character device;or:Orphan symlink;mi:missing file;su:set uid;sg:set gid;tw:sticky other writable;ow:other w\
ritable;st:sticky;ex:executable;"|sed -e 's/:/="/g; s/\;/"\n/g')                                                                                                                                                                            
{                                                                                                                                                                                                                                           
  IFS=:                                                                                                                                                                                                                                     
  for i in $LS_COLORS                                                                                                                                                                                                                       
  do                                                                                                                                                                                                                                        
    echo -e "\e[${i#*=}m$( x=${i%=*}; [ "${!x}" ] && echo "${!x}" || echo "$x" )\e[m"                                                                                                                                                       
  done                                                                                                                                                                                                                                      
}   

スニペットはbashではうまく機能しますが、zshでは機能しません。その理由は、わかりません。 zshで実行すると、次のエラーが発生します。

> sh .test_colors.sh
.eval_colors:1: * not found
[00:fi=00:di=01;34:ln=01;36:pi=40;33:so=01;35:do=01;35:bd=40;33;01:cd=40;33;01:or=40;31;01:su=37;41:sg=30;43:tw=30;42:ow=34;42:st=37;44:ex=01;32:*.tar=01;31:*.tgz=01;31:*.arj=01;31:*.taz=01;31:*.lzh=01;31:*.Zip=01;31:*.z=01;31:*.Z=01;31:*.gz=01;31:*.bz2=01;31:*.deb=01;31:*.rpm=01;31:*.jar=01;31:*.jpg=01;35:*.jpeg=01;35:*.gif=01;35:*.bmp=01;35:*.pbm=01;35:*.pgm=01;35:*.ppm=01;35:*.tga=01;35:*.xbm=01;35:*.xpm=01;35:*.tif=01;35:*.tiff=01;35:*.png=01;35:*.mov=01;35:*.mpg=01;35:*.mpeg=01;35:*.avi=01;35:*.fli=01;35:*.gl=01;35:*.dl=01;35:*.xcf=01;35:*.xwd=01;35:*.flac=01;35:*.mp3=01;35:*.mpc=01;35:*.ogg=01;35:*.wav=01;35:m

更新（2011年11月1日）

以下の@StéphaneGimenezによるスクリプトをテストしました。一部の文字が正しくエスケープされていないように見えることに気づきました。なぜ何か考えはありますか？

回答： @StéphaneGimenezの回答に関するコメントを参照してください。

Answer 1

はるかにクリーンな方法でzsh用に書かれたものと同じです。

#!/bin/zsh

typeset -A names
names[no]="global default"
names[fi]="normal file"
names[di]="directory"
names[ln]="symbolic link"
names[pi]="named pipe"
names[so]="socket"
names[do]="door"
names[bd]="block device"
names[cd]="character device"
names[or]="Orphan symlink"
names[mi]="missing file"
names[su]="set uid"
names[sg]="set gid"
names[tw]="sticky other writable"
names[ow]="other writable"
names[st]="sticky"
names[ex]="executable"

for i in ${(s.:.)LS_COLORS}
do
    key=${i%\=*}
    color=${i#*\=}
    name=${names[(e)$key]-$key}
    printf '\e[%sm%s\e[m\n' $color $name
done

Answer 2

_=_の_${i%=*}_をエスケープする必要があります。そうしないと、サフィックスパターン_=*_が _=_拡張 になるため、_=_は次のように解釈されます。コマンド名。これが_* not found_エラーの原因です。

Zshはデフォルトで変数置換で単語を分割しないため、_$LS_COLORS_は単一の単語に展開されます。 forループを_$LS_COLORS_のコロンで区切られた部分で動作させるには、_for i in $=LS_COLORS_を使用します。または、zshでより慣用的に、IFSを使用せず、代わりに分割方法を明示的に指定します：for i in ${(s.:.)LS_COLORS}。

「名前が_${!x}_である変数の値」を意味する構文_$x_は、bashに固有です。 Zshには、同等の構造であるPパラメーター展開フラグ ：${(P)x}があります。